Hi,IamAaron!

function ytbest --description 'Download Best Video+Audio as MP4 (x264/aac)'
    if test (count $argv) -eq 0
        echo "Usage: ytbest <url>"
        return 1
    end
    yt-dlp --format bestvideo+bestaudio \
        --merge-output-format mp4 \
        $argv \
        --postprocessor-args "-c:v libx264 -preset slow -crf 18 -c:a aac -b:a 192k" \
        --output "%(title)s.%(ext)s"
end

function frg --description 'Search file content with Ripgrep + FZF + Bat preview'
    set result (fzf --disabled --ansi \
        --bind "start:reload:rg --column --line-number --no-heading --color=always --smart-case ''" \
        --bind "change:reload:rg --column --line-number --no-heading --color=always --smart-case {q}" \
        --delimiter : \
        --preview 'bat --style=numbers --color=always --highlight-line {2} {1}' \
        --preview-window 'up,60%,border-bottom,+{2}+3/3,~3')
    if test -n "$result"
        set file_path (echo $result | cut -d: -f1)
        set line_num  (echo $result | cut -d: -f2)
        nano +$line_num $file_path
    end
end

function fgit --description 'Browse git commits with FZF'
    set -l log_line (git log --oneline --color=always | fzf --ansi --no-sort --reverse \
        --preview "git show --color=always (echo {} | cut -d ' ' -f 1) | delta")
    if test -n "$log_line"
        set -l commit_hash (echo $log_line | cut -d ' ' -f 1)
        echo $commit_hash | pbcopy
        echo "Commit hash $commit_hash copied to clipboard!"
    end
end

function spark --description Sparklines
    # spark 1 1 2 5 14 42  →  ▁▁▁▂▃█
    # seq 64 | sort --random-sort | spark
    argparse --ignore-unknown v/version h/help m/min= M/max= -- $argv || return
    if set --query argv[1]
        printf "%s\n" $argv | spark --min="$_flag_min" --max="$_flag_max"
    else
        command awk -v min="$_flag_min" -v max="$_flag_max" '
            { m = min == "" ? m == "" ? $0 : m > $0 ? $0 : m : min
              M = max == "" ? M == "" ? $0 : M < $0 ? $0 : M : max
              nums[NR] = $0 }
            END { n = split("▁ ▂ ▃ ▄ ▅ ▆ ▇ █", s, " ") - 1
              while (++i <= NR) printf("%s", s[(M==m) ? 3 : sprintf("%.f", (1+(nums[i]-m)*n/(M-m)))]) }
        ' && echo
    end
end